みなさん、こんにちは。ＳＵＮです。

リストボックスで文字列が長すぎて表示がはみ出している項目上にマウスポインタ
を移動させると項目の全文字列をヒントとして表示するようにしたTListBoxから
継承したコンポーネントです。

Delphiのコードエディタ下部に表示されるコンパイルエラーリストの様な
コンポーネントです。

また、コンポーネントのフォントの設定がヒント表示に反映するようにしています。





unit HintLstBox;

interface

uses
  Windows, Messages, SysUtils, Classes, Graphics, Controls, Forms, StdCtrls;

type
  TListBoxHintWindow = class(THintWindow)
  private
    procedure ActivateHintData(Rect: TRect; const AHint: string;
        AData: Pointer); override;
  end;

  THintListBox = class(TListBox)
  private
    procedure CMHintShow(var Message: TMessage); message CM_HINTSHOW;
  end;

procedure Register;

implementation

procedure Register;
begin
  RegisterComponents('Samples', [THintListBox]);
end;


{ THintListBox }

// ﾋﾝﾄが表示される時に呼ばれるﾒｯｾｰｼﾞﾊﾝﾄﾞﾗ
procedure THintListBox.CMHintShow(var Message: TMessage);
var
  Index: Integer;
begin
  with THintInfo(Pointer(Message.LParam)^) do // LParamをTHintInfo型にｷｬｽﾄ
  begin
    HintStr := '';                            // ﾋﾝﾄ文字列を空にする
    HintWindowClass := TListBoxHintWindow;    // ﾋﾝﾄ表示を独自の方法で行う
    Index := CursorPos.y div ItemHeight + TopIndex;// ﾏｳｽのある項目のｲﾝﾃﾞｯｸｽ
    Canvas.Font.Assign(Font);           // CanvasのFontをｺﾝﾎﾟｰﾈﾝﾄと同じにする

    // ｲﾝﾃﾞｯｸｽの範囲が正しく,項目の文字列が全て表示していない場合はﾋﾝﾄを表示
    if (Index < Items.Count) and
       (Canvas.TextWidth(Items[Index]) > ClientWidth) then
    begin
      HintStr := Items[Index];          // ﾋﾝﾄ文字列に項目の文字列を設定
      HintData := Font;                 // ﾌｫﾝﾄ情報をﾋﾝﾄに渡す
      CursorRect := ItemRect(Index);    // ﾋﾝﾄ表示対象ｴﾘｱ（※）の設定
      HintPos.x := CursorRect.Left - 1; // ﾋﾝﾄ表示場所の設定
      HintPos.y := CursorRect.Top - 3;
      HintPos := ClientToScreen(HintPos); // ﾋﾝﾄ表示場所を画面座標に変換

      // ※ ﾋﾝﾄ表示対象ｴﾘｱ  ･･･ このｴﾘｱからﾏｳｽが出た場合にﾋﾝﾄが表示し直され
      //      ます。これをﾋﾝﾄ表示中の項目のｴﾘｱにしておくと、ﾏｳｽが違う項目に
      //      移動すると移動先の項目のﾋﾝﾄが表示されます。
    end;
  end;
end;


{ TListBoxHintWindow }

// 実際にﾋﾝﾄを表示する場合に実行されるﾒｿｯﾄﾞ
procedure TListBoxHintWindow.ActivateHintData(Rect: TRect;
      const AHint: string; AData: Pointer);
begin
  // ﾋﾝﾄのﾌｫﾝﾄをｺﾝﾎﾟｰﾈﾝﾄと同じにする
  Canvas.Font.Assign(TFont(AData));

  // ﾌｫﾝﾄの変更によりﾋﾝﾄｳｨﾝﾄﾞｳｻｲｽﾞの再設定が必要
  Rect.Right := Rect.Left + Canvas.TextWidth(AHint)+5;
  Rect.Bottom := Rect.Top + Canvas.TextHeight(AHint)+2;

  // 実際の描画はﾃﾞﾌｫﾙﾄのまま
  inherited ActivateHintData(Rect, AHint, AData)
end;

end.

                                                    ＳＵＮでした。

Original document by ＳＵＮ          氏 ID:(RXK14115)

ここにあるドキュメントは NIFTY SERVEの Delphi Users' Forum の16番会議室「玉石混淆みんなで作るSample蔵」に投稿されたサンプルです。これらのサンプルはボーランド株式会社がサポートする公式のものではありません。また、必ずしも動作が検証されているものではありません。これらのサンプルを使用したことに起因するいかなる損害も投稿者、およびフォーラムスタッフはその責めを負いません。使用者のリスクの範疇でご使用下さい。