この発言は
#01206　大怪獣もぎゃ    さんの他のプログラムの出力結果を得る
に対するコメントです



みなさま、もぎゃあ♪
大怪獣もぎゃです。



　先の奴はbatファイルにコマンドを吐き出して走らせ、
さらに結果もテキストファイルに吐き出させて持って来るという、
なかなか強引なことをやっておりますが、
きっちりやるのであれば、パイプというものがあるらしいです。
nifty:FDELPHI/MES/11/7678 稀杜 さんThanks!

　ただ、こいつでやるとCOMMAND.COMのコマンドがそのままでは
通らなくなるんですよねぇ。。
　command c 命令 の形で走らせれば動作すると思います。

function getProcessResultbyPipe(process:string):string;
const
  BUFFER_SIZE = 4000;
var
  si: TStartUpInfo;
  pi: TProcessInformation;
  sa: TSecurityAttributes;

  LBuffer: string;
  hReadPipe, hWritePipe: THandle;
  LSize: Cardinal;
begin
  GetStartUpInfo(si);

  //ウィンドウの表示・非表示
  si.dwFlags := STARTF_USESHOWWINDOW;
  si.wShowWindow := SW_HIDE;

  //TSecurityAttributes構造体の設定
  sa.nLength := SizeOf(sa);
  sa.bInheritHandle := True;
  sa.lpSecurityDescriptor := nil;

  //匿名パイプの作成
  CreatePipe(hReadPipe, hWritePipe, @sa, BUFFER_SIZE);

  si.dwFlags := si.dwFlags or STARTF_USESTDHANDLES;
  si.hStdOutput := hWritePipe; //標準出力と
  //si.hStdError := hWritePipe; //標準エラー

  //プログラム起動
  if not CreateProcess(PChar(process),nil, nil, nil, True,
    0, nil, nil, si, pi) then
  begin
    Raise Exception.Create(process+'を起動することができませんでした:' +
IntToStr(GetLastError));
  end;

  //終了待ち
  while WaitForSingleObject(pi.hProcess, 100) = WAIT_TIMEOUT do
  begin
    Sleep(100);
  end;

  SetLength(LBuffer, BUFFER_SIZE);
  CloseHandle(hWritePipe);
  ReadFile(hReadPipe, PChar(LBuffer)^, BUFFER_SIZE, LSize, nil);
  SetLength(LBuffer, LSize);

  result := LBuffer;
  CloseHandle(hReadPipe);
  CloseHandle(pi.hThread);
  CloseHandle(pi.hProcess);
end;

                        2000/12/04(Mon) 00:12pm  CQK00014 大怪獣もぎゃ
 


- FDELPHI  MES(16):玉石混淆みんなで作るSample蔵【見本蓄積】 00/12/11 -

Original document by 大怪獣もぎゃ    氏 ID:(CQK00014)

ここにあるドキュメントは NIFTY SERVEの Delphi Users' Forum の16番会議室「玉石混淆みんなで作るSample蔵」に投稿されたサンプルです。これらのサンプルはボーランド株式会社がサポートする公式のものではありません。また、必ずしも動作が検証されているものではありません。これらのサンプルを使用したことに起因するいかなる損害も投稿者、およびフォーラムスタッフはその責めを負いません。使用者のリスクの範疇でご使用下さい。